UOG: Demise

Hello everyone,
I'm just getting ready to start playing again after 2 years.
I know that I missed some updates, and my macros rn no longer works.
A message says: " The feature 'speech journal checks' is not allowed on this server."

What I supposed to do in that case?
Here's the macros that I always use:

MINING MAGERY:
//1. need 2 full runebooks marked 1 tile south of the mineable locations
//2. macro assumes you have tinkering and spot at dropoff location to restock ingots
//3. Organizer agent 'Ore' needs to be configured from your backpack to dropoff container and have the 4 ore graphics and 6 mining gems
//4. pauses after recalls are set to 2000 for 0Faster Casting. Change to 1750 for 1FC and 1500 for 2FC
if not @findobject 'IngotsSource'
promptalias 'IngotsSource'
endif
if not @findobject 'OreBookOne'
promptalias 'OreBookOne'
endif
if not @findobject 'OreBookTwo'
promptalias 'OreBookTwo'
endif
if not @findobject 'HomeOre'
promptalias 'HomeOre'
endif
if not listexists 'OreBook'
createlist 'OreBook'
pushlist 'OreBook' 'OreBookOne'
pushlist 'OreBook' 'OreBookTwo'
endif
if not listexists 'Runes'
createlist 'Runes'
pushlist 'Runes' 5
pushlist 'Runes' 11
pushlist 'Runes' 17
pushlist 'Runes' 23
pushlist 'Runes' 29
pushlist 'Runes' 35
pushlist 'Runes' 41
pushlist 'Runes' 47
pushlist 'Runes' 53
pushlist 'Runes' 59
pushlist 'Runes' 65
pushlist 'Runes' 71
pushlist 'Runes' 77
pushlist 'Runes' 83
pushlist 'Runes' 89
pushlist 'Runes' 95
endif
For 0 to 'OreBook'
For 0 to 'Runes'
pause 500
clearjournal
pause 500
useobject OreBook[]
waitforgump 0x554b87f3 5000
replygump 0x554b87f3 Runes[]
//tells you which rune you are on, see runelist above
sysmsg 'Rune' 33
sysmsg Runes[] 33
pause 2000
while not @injournal 'no metal here' and not @injournal "can't mine that"
//use pickaxe to northern tile until specified weight is reached
pause 300
usetype 0xe86
waitfortarget 1000
targettileoffset 0 -1 0
// once weight is reached go home, if getting overweight, lower it
if weight > 475
useobject 'HomeOre'
waitforgump 0x554b87f3 5000
replygump 0x554b87f3 5
pause 2000
// organizer to put up ore
organizer 'Ore'
while organizing
endwhile
// get ingots if low
if counttype 0x1bf2 0 'backpack' < 20
useobject 'IngotsSource'
pause 1000
movetype 0x1bf2 'IngotsSource' 'backpack' (0 0 0) 0 40
pause 1000
endif
// kits
while @counttype 0x1eb8 0 'backpack' < 2
usetype! 0x1eb8
waitforgump 0x38920abd 15000
replygump 0x38920abd 8
waitforgump 0x38920abd 15000
replygump 0x38920abd 23
endwhile
//pickaxes
while @counttype 0xe86 0 'backpack' < 3
usetype! 0x1eb8
waitforgump 0x38920abd 15000
replygump 0x38920abd 8
waitforgump 0x38920abd 15000
replygump 0x38920abd 114
endwhile
//recall back to where you were
useobject OreBook[]
waitforgump 0x554b87f3 5000
replygump 0x554b87f3 Runes[]
pause 2000
endif
endwhile
endfor
//recall home so ingot container is found
pause 1000
useobject 'HomeOre'
waitforgump 0x554b87f3 5000
replygump 0x554b87f3 5
pause 2000
endfor

LUMBER MAGERY:
//Magery Version
//1. need 2 full runebooks marked 1 tile south and same elevation of the choppable tree
//2. Organizer agent 'Boards' needs to be configured from your backpack to dropoff container with boards and 5 specials on it
//3. pauses after recalls are set to 2000 for 0fc. Change to 1750 for 1fc and 1500 for 2fc
if not @findobject 'TreeBookOne'
promptalias 'TreeBookOne'
endif
if not @findobject 'TreeBookTwo'
promptalias 'TreeBookTwo'
endif
if not @findobject 'HomeLumber'
promptalias 'HomeLumber'
endif
if not listexists 'TreeBook'
createlist 'TreeBook'
pushlist 'TreeBook' 'TreeBookOne'
pushlist 'TreeBook' 'TreeBookTwo'
endif
if not listexists 'Runes'
createlist 'Runes'
pushlist 'Runes' 5
pushlist 'Runes' 11
pushlist 'Runes' 17
pushlist 'Runes' 23
pushlist 'Runes' 29
pushlist 'Runes' 35
pushlist 'Runes' 41
pushlist 'Runes' 47
pushlist 'Runes' 53
pushlist 'Runes' 59
pushlist 'Runes' 65
pushlist 'Runes' 71
pushlist 'Runes' 77
pushlist 'Runes' 83
pushlist 'Runes' 89
pushlist 'Runes' 95
endif
For 0 to 'TreeBook'
For 0 to 'Runes'
pause 500
clearjournal
pause 500
useobject TreeBook[]
waitforgump 0x554b87f3 5000
replygump 0x554b87f3 Runes[]
//tells you which rune you are on, see runelist above
sysmsg 'Rune' 33
sysmsg Runes[] 33
pause 2000
//equips axe if it's not SC
if not @findobject 'lefthand'
//change type to your axe
if findtype 0xf47 0 'backpack'
setalias 'axe' 'found'
equipitem 'axe' 2
endif
endif
while not @injournal 'enough wood here'
pause 300
//chop logs to boards
if @findtype 0x1bdd 'any' 'backpack'
useobject 'LeftHand'
waitfortarget 1000
target! 'found'
else
//chop trees
useobject 'LeftHand'
waitfortarget 1000
targettileoffset 0 -1 0
endif
// Change this if your getting overweight, Subtract 25 from your max weight.
if weight > 480
//make remaining logs boards
while @findtype 0x1bdd 'any' 'backpack'
useobject 'LeftHand'
waitfortarget 1000
target! 'found'
pause 500
endwhile
//recall home
useobject 'HomeLumber'
waitforgump 0x554b87f3 5000
replygump 0x554b87f3 5
pause 2000
//unload
organizer 'Boards'
while organizing
pause 500
endwhile
//go back to where you were
useobject TreeBook[]
waitforgump 0x554b87f3 5000
replygump 0x554b87f3 Runes[]
pause 2000
//re-equip axe if needed
if not @findobject 'lefthand'
equipitem 'axe' 2
pause 1000
endif
endif
if @injournal 'use an axe'
break
endif
endwhile
endfor
endfor

Play old school way

change every:
@injournal 'messagehere'
with:
@injournal 'messagehere' 'system'

S7orm wrote: ↑October 15th, 2019, 5:03 pm change every:
@injournal 'messagehere'
with:
@injournal 'messagehere' 'system'

it works! tks!!!

Thanks for the help S7orm!